@echo off
setlocal
rem Kaynakca Dogrula - Word eklentisi kurulumu (Windows, masaustu Word).
rem Kaynak ve yardim: https://www.kaynakcadogrula.com/word-eklenti
rem Yaptigi is: manifest.xml dosyasini kullanici klasorune indirir, Word'un gelistirici
rem eklentileri kaydina (HKCU) ekler ve eklentiyi etkinlestiren bos bir belgeyi bir kez acar.
rem Yonetici izni gerekmez; sistem ayarlarina dokunmaz. Kaldirmak icin: kaldir.cmd

set "D=%LOCALAPPDATA%\KaynakcaDogrula"
set "BASE=https://kaynakcadogrula.com/word-eklenti"
echo.
echo  Kaynakca Dogrula - Word eklentisi kuruluyor...
echo.
tasklist /FI "IMAGENAME eq WINWORD.EXE" 2>nul | find /I "WINWORD.EXE" >nul
if not errorlevel 1 (
  echo  Lutfen once Word'u tamamen kapatin, sonra bu dosyayi yeniden calistirin.
  echo.
  pause
  exit /b 1
)
if not exist "%D%" mkdir "%D%"
curl -sSL -o "%D%\manifest.xml" "%BASE%/manifest.xml" || goto :err
curl -sSL -o "%D%\baslat.docx" "%BASE%/baslat.docx" || goto :err
reg add "HKCU\Software\Microsoft\Office\16.0\WEF\Developer" /v KaynakcaDogrula /t REG_SZ /d "%D%\manifest.xml" /f >nul || goto :err
rem Baslat menusune kisayol: Word'u bu belgeyle acmak eklentiyi o oturum icin etkinlestirir.
powershell -NoProfile -Command "$s=(New-Object -ComObject WScript.Shell).CreateShortcut([IO.Path]::Combine($env:APPDATA,'Microsoft\Windows\Start Menu\Programs\Kaynakca Dogrula (Word).lnk')); $s.TargetPath='%D%\baslat.docx'; $s.Description='Word''u Kaynakca Dogrula eklentisi etkin olarak acar'; $s.Save()" >nul 2>&1
echo  Kurulum tamamlandi. Word aciliyor; "Kaynakcayi Kontrol Et" dugmesi Giris seridinin sagindadir.
echo.
echo  NOT: Word'u sonraki acislarinizda dugme icin Giris seridinde Eklentiler'e tiklayip
echo  "Gelistirici Eklentileri" altindaki Kaynakca Dogrula'yi secin (iki tik) ya da Baslat
echo  menusundeki "Kaynakca Dogrula (Word)" kisayoluyla acin.
echo  Kaldirmak icin: %BASE%/kaldir.cmd
start "" "%D%\baslat.docx"
ping -n 4 127.0.0.1 >nul
exit /b 0

:err
echo.
echo  Kurulum basarisiz oldu. Internet baglantinizi kontrol edip yeniden deneyin.
echo  Yardim: %BASE%
pause
exit /b 1